自分はオンラインストレージサービスは「SugarSync」の30GBプランと「Dropbox」の無料プランを併用し、3台のMac間で使っていました。

どうも最近SugarSyncで同期しているデータの総容量と、SugarSyncファイルマネージャに表示されている総容量が違うよなー（ファイルマネージャに表示されている方が数GB多い）と思い一度Magic Briefcaseも含めバックアップをローカルに取ってから3台のMac全て同期していたフォルダを解除しました（Magic Briefcaseはフォルダ内を空に）。

これでちゃんとファイルマネージャ側の表示も0になればいいかーと思ったら【5.6GB使用済み | 30.00GB使用済み】と表示されている！

ん？？なんで？？

Deleted Files内のデータも空にしたのになぜ？

というわけでsugarsync.jpに問い合せてみた。内容は上に書いたことをほぼまんま。

返信は次の日にきました。返信内容は以下のような感じ。

=========================================

◆「削除済みファイル」フォルダの確認

「削除済みファイル」フォルダには5代前までのファイルが保存されており、削除を行わない限り、容量を消費いたします。
このため「削除済みファイル」フォルダをご確認いただき、不要なファイルがございましたら、完全削除をお願いいたします。

◆不要なコンピュータの削除

既に利用していないコンピュータで容量を消費しているケースがございます。
このため、既に利用していないコンピュータにつきましては、登録を削除していただけますようお願いいたします。

◆ストレージの再利用の実施

ストレージ上で、パソコンとのリンクが切れているため表示されないファイルが容量を消費しているケースがございます。
このため、ストレージの再利用機能を用いて、以下の手順でファイルの削除をお試しいただけますようお願いいたします。
※利用されているパソコン全てでお試しください。

＜ストレージの再利用方法＞
1.SugarSyncファイルマネージャのメニューより「ツール(T)」−「ストレージの再利用(S)」をクリックします。

2.画面上にリンク切れで表示できないファイルが表示されますので、それらをご選択いただき、「削除済みファイル」（もしくは「ウェブアーカイブ」）をクリックします。

3.2の手順で選択したフォルダへファイルが移動しますので、必要に応じて削除を行ってください。

◆切断されたフォルダの確認

「ストレージの再利用」と同様に、リンクが切断されたファイルが存在している場合がございます。
このため、以下の手順で切断されたフォルダの確認、削除をお試しください。

1.SugarSyncファイルマネージャより画面左上の「同期フォルダの管理(M)」をクリックします。

2.「他のコンピュータ」の枠内に、切断されたフォルダとしてフォルダ名が表示されているかをご確認ください。

3.切断されたフォルダにフォルダが表示されている場合、フォルダ名をクリックのうえ「編集」をクリックします。

4.切断されたフォルダ画面にて「削除」をクリックし、ファイルを削除します。
　※ファイルを再同期させる場合は、「同期」をクリックし、ファイルの格納場所を設定してください。

5.同期フォルダ管理画面を[OK]をクリックして閉じます。

=========================================

結果としては【◆切断されたフォルダの確認】が原因でした。
ただ自分の場合3台全てで同期解除を確認していたのでそんなはずはないと思っていたのですが。
で、何をやったかというと一度全ての同期しているPCで「ツール」→「コンピュータの削除」を実行します。
そのあとどれか1台のPCを再度登録、ファイルマネージャで「同期フォルダの管理」を見てみると「他のコンピュータ」のところに削除されていなフォルダが！これを削除すると使用済み容量が0になりました！

SugarSyncはフォルダ毎に同期を設定できるのは便利なのですが、ファイルマネージャが結構メモリくったり、なぜか同期しているデータのファイル名が勝手に全て大文字になったりと不便な点も多いので今後はDropboxだけにしようかと思います。

SugarSyncで有料プランから無料プランに変更する場合は使用済み容量を5GB未満にしておかないと勝手にお金を取られちゃいます。この辺の仕様もどうなんだ。。。って感じでだいぶ不信感が出ました。あとカード情報も削除できないっていう。アカウント削除する場合はわざわざメールしなくちゃいけないみたいです！

とりあえずこの記事と同じものを2.1aで作ってみました。
2.1aからPlayer9と10でわかれたっぽい。ライブラリはこちらから。
今回はPlayer9の方で作りました。

2.0.2と見比べながら。まずは2.0.2ではあったb2AABBクラスが不要に。
b2Worldのコンストラクタの第一引数にいれてたけどそれもなくなりました。

//2.0.2
var worldAABB : b2AABB = new b2AABB();
worldAABB.lowerBound.Set( -100, -100);
worldAABB.upperBound.Set(100, 100);

var world : b2World = new b2World(worldAABB, gravity, true);

//2.1a
var world : b2World = new b2World(gravity, true);

2.1aで重要になってくるのがb2FixtureDefクラス。ドキュメントには

A fixture definition is used to create a fixture. This class defines an abstract fixture definition. You can reuse fixture definitions safely.

と書いてある。fixtureは【固定具・固定】とかいう意味。このクラスは再利用できて固定具の定義に使うよって意味であってるかな。
上のFlashでいう固定具ってのは壁とかCircleとかBoxとかのオブジェクト。

また、b2Bodyクラスも再利用する。

A body definition holds all the data needed to construct a rigid body. You can safely re-use body definitions.

rigid bodyもここでいう壁やCircleなどのオブジェクトととらえていいと思う。そういうオブジェクト全てを管理する。

例えばCircleを一つ定義するとなるとこんな感じ。

//2.0.2
var circleBodyDef:b2BodyDef = new b2BodyDef();
circleBodyDef.position.Set(100 / m_physScale, 20 / m_physScale);

var circleShapeDef:b2CircleDef = new b2CircleDef();
circleShapeDef.radius = 50 / m_phyScale ;
circleShapeDef.density = 1;             //密度
circleShapeDef.friction = 0.2;          //摩擦
circleShapeDef.restitution = 0.1;     //反発係数

var circleBody:b2Body = world.CreateBody(circleBodyDef);
circleBody.CreateShape(circleShapeDef);
circleBody.SetMassFromShapes();

//2.1a
var bodyDef : b2BodyDef = new b2BodyDef();
var fixtureDef : b2FixtureDef = new b2FixtureDef();
var circleDef : b2CircleShape = new b2CircleShape();
fixtureDef.density = 1;
fixtureDef.friction = 0.2;
fixtureDef.restitution = 0.1;
fixtureDef.shape = circleDef;
bodyDef.type = b2Body.b2_dynamicBody;

circleDef.SetRadius(radius / m_physScale);
bodyDef.position.Set(100 / m_physScale, 20 / m_physScale);
var circleBody : b2Body = world.CreateBody(bodyDef);
circleBody.CreateFixture(fixtureDef);

b2FixtureDefインスタンスとb2Bodyインスタンスは再利用ができる。最後にソース全部のっけるのでそこ参照。
またここでいうCircleやBoxなど動かしたいものはb2BodyDefインスタンスのtypeプロパティにb2Body.b2_dynamicBodyを代入する。
uint型なので2を代入してもいい。静的なものはb2_staticBodyか0、kinematicはb2_kinematicBodyか1。
dynamicBodyを代入したあと静的なものを作る場合はちゃんとstaticBodyを代入するのを忘れずに。

あとb2DebugDrawのm_fillAlphaやm_drawScaleプロパティが全てメソッド定義に変わっている。

//2.0.2
var m_sprite : Sprite = new Sprite();
addChild(m_sprite);
var debugDraw:b2DebugDraw = new b2DebugDraw();
debugDraw.m_fillAlpha = 0.3;
debugDraw.m_drawScale = m_physScale;
debugDraw.m_lineThickness = 1;
debugDraw.m_sprite = m_sprite;
debugDraw.m_drawFlags = b2DebugDraw.e_shapeBit;
world.SetDebugDraw(debugDraw);

//2.1a
var m_sprite : Sprite = new Sprite();
addChild(m_sprite);
var debugDraw : b2DebugDraw = new b2DebugDraw();
debugDraw.SetFillAlpha(0.3);
debugDraw.SetDrawScale(m_physScale);
debugDraw.SetLineThickness(1);
debugDraw.SetSprite(m_sprite);
debugDraw.SetFlags(b2DebugDraw.e_shapeBit);
world.SetDebugDraw(debugDraw);

以下全ソースです。ちょっと触ってみただけなので間違いなどあれば指摘ください

package
{
	import Box2D.Collision.Shapes.b2CircleShape;
	import Box2D.Collision.Shapes.b2PolygonShape;
	import Box2D.Common.Math.b2Vec2;
	import Box2D.Dynamics.b2Body;
	import Box2D.Dynamics.b2BodyDef;
	import Box2D.Dynamics.b2DebugDraw;
	import Box2D.Dynamics.b2FixtureDef;
	import Box2D.Dynamics.b2World;

	import fl.controls.Button;

	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;

	/**
	 * @author laqu
	 */
	public class Index extends Sprite
	{
		const WIDTH : uint = 400;
		const HEIGHT : uint = 300;
		const OBJ_NUM : uint = 20;

		private var _world : b2World;
		private var _fixtureDef : b2FixtureDef;
		private var _m_physScale : uint = 100;
		private var _m_sprite : Sprite;
		private var _m_iterations : int = 10;
		private var _m_timeStep : Number = 1 / 30;
		private var _m_positionIterations : uint = 10;
		private var _objArr : Array = [];
		private var _btn:Button;

		public function Index()
		{
			init();
		}

		private function init() : void
		{
			var i : uint;
			var gravity : b2Vec2 = new b2Vec2(0, 10);

			_world = new b2World(gravity, true);
			_fixtureDef = new b2FixtureDef();

			var bodyDef : b2BodyDef = new b2BodyDef();

			//壁・上下左右
			var wallBody : b2Body;
			var wallDef : b2PolygonShape = new b2PolygonShape();
			var wallWidth : Array = [WIDTH / 2,5];
			var wallHeight : Array = [5,HEIGHT / 2];
			var wallX : Array = [WIDTH / 2,0 ,WIDTH / 2,WIDTH];
			var wallY : Array = [0,HEIGHT / 2,HEIGHT,HEIGHT / 2];
			_fixtureDef.density = 1;
			_fixtureDef.friction = 1;
			_fixtureDef.shape = wallDef;

			for(i = 0;i < 4;i++)
			{
				bodyDef.position.Set(wallX[i] / _m_physScale, wallY[i] / _m_physScale);
				wallDef.SetAsBox(wallWidth[i % 2] / _m_physScale, wallHeight[i % 2] / _m_physScale);
				wallBody = _world.CreateBody(bodyDef);
				wallBody.CreateFixture(_fixtureDef);
			}

			//Circle
			var circleDef : b2CircleShape = new b2CircleShape();
			_fixtureDef.friction = 10;
			_fixtureDef.density = 10;
			_fixtureDef.restitution = 0.9;
			_fixtureDef.shape = circleDef;
			bodyDef.type = b2Body.b2_dynamicBody;

			for(i = 0;i < OBJ_NUM;i++)
			{
				var radius : uint = Math.random() * 20 + 10;
				circleDef.SetRadius(radius / _m_physScale);
				bodyDef.position.Set(Math.random() * WIDTH / _m_physScale, Math.random() * HEIGHT / _m_physScale);
				var circleBody : b2Body = _world.CreateBody(bodyDef);
				circleBody.CreateFixture(_fixtureDef);
				_objArr.push(circleBody);
			}

			//Box
			var boxDef : b2PolygonShape = new b2PolygonShape();
			_fixtureDef.friction = 1;
			_fixtureDef.density = 1;
			_fixtureDef.restitution = 0.1;
			_fixtureDef.shape = boxDef;
			bodyDef.type = b2Body.b2_dynamicBody;

			for(i = 0;i < OBJ_NUM;i++)
			{
				var boxWidth : uint = Math.random() * 20 + 5;
				var boxHeight : uint = Math.random() * 20 + 5;
				boxDef.SetAsBox(boxWidth / _m_physScale, boxHeight / _m_physScale);
				bodyDef.position.Set(Math.random() * WIDTH / _m_physScale,Math.random() * HEIGHT / _m_physScale);
				var boxBody:b2Body = _world.CreateBody(bodyDef);
				boxBody.CreateFixture(_fixtureDef);
				_objArr.push(boxBody);
			}

			//DebugDraw
			_m_sprite = new Sprite();
			addChild(_m_sprite);

			var debugDraw : b2DebugDraw = new b2DebugDraw();
			debugDraw.SetSprite(_m_sprite);
			debugDraw.SetFillAlpha(0.3);
			debugDraw.SetDrawScale(_m_physScale);
			debugDraw.SetLineThickness(1);
			debugDraw.SetFlags(b2DebugDraw.e_shapeBit);
			_world.SetDebugDraw(debugDraw);

			addEventListener(Event.ENTER_FRAME, update);

			//Btn
			_btn = new Button();
			_btn.label = "Button";
			_btn.x = _btn.y = 20;
			_btn.addEventListener(MouseEvent.CLICK, btnClick);
			addChild(_btn);
		}

		//ボタンをクリックしたら上方向に力を加える
		private function btnClick(e : MouseEvent) : void
		{
			for(var  i : uint = 0;i < OBJ_NUM*2;i++)
			{
				var body:b2Body = _objArr[i] as b2Body;
				body.SetLinearVelocity(new b2Vec2(0,-Math.random()*10));
				//SetAwakeしないと全てのオブジェクトが静止した場合に動かない
				body.SetAwake(true);
			}
		}

		//レンダリング
		private function update(e : Event) : void
		{
			_world.Step(_m_timeStep, _m_iterations, _m_positionIterations);
			_world.ClearForces();
			_world.DrawDebugData();
		}
	}
}

ラジオボタンON・OFF切り替え後、LoadMovieボタンをクリックでムービーを読み込みます。
以下LoadMovieクリック後のソース抜粋です。_soundGroupはON・OFFのRadioButtonGroupです。

//ラジオボタンがOFFだったら
if(_soundGroup.selection.value == "sound_off")
{
	var on_mc : Sprite = _player.muteButton.getChildAt(0) as Sprite;
	on_mc.dispatchEvent(new MouseEvent(MouseEvent.CLICK));
}

ただし、これはスキン内のインスタンスを参照しているのでスキンが読み込まれた後じゃないとエラーがでます。
スキンが読み込まれたかどうかはVideoEvent.SKIN_LOADEDを使用します。
以下LoadMovieクリック後の流れ。
実際にはローディングテキストなど他の処理も含まれていますが今回はその辺は重要じゃないので省きます。

private function loadFlv(e : MouseEvent) : void
{
	_player = new FLVPlayback();
	_player.setSize(420, 280);
	_player.skin = "スキンのパス";
	_player.source = "ムービーのパス";
	_player.autoPlay = true;
	_player.addEventListener(VideoEvent.COMPLETE, complete);
	_player.addEventListener(VideoEvent.READY, videoReady);
	_player.addEventListener(VideoEvent.SKIN_LOADED, skinLoaded);
}

private function skinLoaded(e : VideoEvent) : void
{
	_player.removeEventListener(VideoEvent.SKIN_LOADED, skinLoaded);

	//ラジオボタンがOFFだったら
	if(_soundGroup.selection.value == "sound_off")
	{
		var on_mc : Sprite = _player.muteButton.getChildAt(0) as Sprite;
		on_mc.dispatchEvent(new MouseEvent(MouseEvent.CLICK));
	}
}

private function videoReady(e : VideoEvent) : void
{
	_player.removeEventListener(VideoEvent.READY, videoReady);
	addChild(_player);
}

private function complete(e : VideoEvent) : void
{
	_player.play();
}

まずはFlash側。

package classes
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLLoader;
	import flash.net.URLLoaderDataFormat;
	import flash.net.URLRequest;
	import flash.net.URLRequestMethod;
	import flash.net.URLVariables;

	public class Index extends Sprite
	{
		private var _urlLoader : URLLoader;
		private var _req : URLRequest;
		private var _variables : URLVariables;

		public function Index()
		{
			init();
		}

		private function init() : void
		{
			_variables = new URLVariables();
			_variables.sendData = "huga";

			_req = new URLRequest();
			_req.url = "URLを代入";
			_req.method = URLRequestMethod.POST;
			_req.data = _variables;

			_urlLoader = new URLLoader();
			_urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
			_urlLoader.addEventListener(Event.COMPLETE, complete);
			_urlLoader.load(_req);
		}

		private function complete(e : Event) : void
		{
			_urlLoader.removeEventListener(Event.COMPLETE, complete);

			var data : URLVariables = new URLVariables(_urlLoader.data);
			trace(data.reciveData);
		}
	}
}

Ruby側。

#!/usr/bin/env ruby

require 'cgi'

print "Content-type:text/plain\n\n"

cgi = CGI.new
hoge = cgi["sendData"]
print "reciveData=" + hoge

パブリッシュしてhugaと出ればOK。
まあ、簡単ですよね。

たまにAS以外の言語に触れると楽しいです。
rubyでflickrAPIたたいて表示してるだけです。

使ってるjQueryはこつら。
・Create a Thumbnail Gallery with Slick Heading and Caption Effect with jQuery
・How to Create a Visual Image Preloader using jQuery « Dino Latoga

IEで見るとCSSの角丸がきいてなかったり、ロールオーバー時のキャプションの背景が透過じゃなかったり残念なのでIE以外をお薦めします。

package classes
{
	import flash.events.Event;

	import org.papervision3d.view.BasicView;
	import org.papervision3d.materials.WireframeMaterial;
	import org.papervision3d.objects.DisplayObject3D;
	import org.papervision3d.objects.primitives.Cone;
	import org.papervision3d.objects.primitives.Plane;

	import jiglib.plugin.papervision3d.Papervision3DPhysics;
	import jiglib.plugin.papervision3d.Pv3dMesh;
	import jiglib.geometry.JBox;

	[SWF(width="450",height="300",backgroundColor="#ffffff",frameRate="30")]

	public class Main extends BasicView
	{
		private var rootNode : DisplayObject3D;
		private var physics : Papervision3DPhysics;

		public static const FROOR_SIZE : uint=2000;
		public static const CONE_NUM : uint=5;
		public static const CONE_RADIUS : uint=80;
		public static const CONE_HEIGHT : uint=200;

		public function Main():void
		{
			super(450,300,false);
			init();
		}

		private function init():void
		{
			camera.y = 400;
			camera.z = -1500;

			rootNode = new DisplayObject3D  ;
			scene.addChild(rootNode);

			physics = new Papervision3DPhysics(rootNode,9.8);

			var floor:Plane = new Plane(new WireframeMaterial(0),FROOR_SIZE,FROOR_SIZE);
			rootNode.addChild(floor);
			var floorBox : JBox=new JBox(new Pv3dMesh(floor),FROOR_SIZE,1,FROOR_SIZE);
			floorBox.y = -500;
			floorBox.rotationX = 90;
			floorBox.movable = false;
			physics.addBody(floorBox);

			for (var i : uint = 0; i < cone_NUM; i++)
			{
				var cone : Cone = new Cone(new WireframeMaterial(0xFF0000),CONE_RADIUS,CONE_HEIGHT,6,4);
				scene.addChild(cone);
				var coneBox : JBox = new JBox(new Pv3dMesh(cone),CONE_RADIUS*2,CONE_RADIUS*2,CONE_HEIGHT);
				coneBox.y = 1000;
				coneBox.friction = 0.2;
				coneBox.restitution = 1.2;
				physics.addBody(coneBox);
			}

			startRendering();
		}

		protected override function onRenderTick(e:Event=null):void
		{
			physics.step();
			super.onRenderTick(e);
		}
	}
}

自分が喋ってるとこはほんのちょこっとですが機会があれば覗いてみてください。

CocoaとObjective-Cの本買ってiPhoneアプリを勉強中。
今は簡単なのしか作れないけどつくってみたいのとかあるからiPhone Developer Programに加入しようかなぁと。
でないとSimulatorで確認はできても実機で試すこともできない。

年間一万ちょいだからそんな高額でもないし。
ただ今月は金がない。それだけ。

jiglib 3D Physics Engineという各種3Dライブラリで物理シミュレーションを行うことができるライブラリを触ってみました。

対応している3Dライブラリはjiglibのバージョンr92の時点でPapervision3D・Away3D・Sandyの3つ。

自分はPV3Dしか使ったことないのでPV3D+jiglibの環境です。

package
{
	import flash.events.Event;

	import org.papervision3d.view.BasicView;
	import org.papervision3d.materials.WireframeMaterial;
	import org.papervision3d.materials.utils.MaterialsList;
	import org.papervision3d.objects.DisplayObject3D;

	import jiglib.plugin.papervision3d.Papervision3DPhysics;
	import jiglib.physics.RigidBody;

	import net.hires.debug.Stats;

	/**
	 * @author laqu
	 */
	public class Main extends BasicView
	{
		private var rootNode:DisplayObject3D;
		private var physics:Papervision3DPhysics;
		private var floor:RigidBody;

		public static const CUBE_SIZE:uint=150;
		public static const CUBE_NUM:uint=15;

		//Constructor
		public function Main():void
		{
			super(450,300,false);
			stage.quality="low";
			init();
		}

		private function init() : void
		{
			addChild(new Stats());

			rootNode=new DisplayObject3D();
			scene.addChild(rootNode);

			camera.y=400;
			camera.z=-2000;

			physics=new Papervision3DPhysics(rootNode,9.8);

			//Create Floor
			floor=physics.createGround(new WireframeMaterial(0), 2000, 0);
			floor.y=-500;

			//Create Cubes
			for(var i:uint=0;i < Main.CUBE_NUM;i++)
			{
				var matlist:MaterialsList=new MaterialsList();
				matlist.addMaterial(new WireframeMaterial(Math.random()*0xffffff),"all");
				var cube:RigidBody=physics.createCube(matlist, Main.CUBE_SIZE, Main.CUBE_SIZE, Main.CUBE_SIZE);
				cube.restitution=1.2;
				cube.friction=0.2;
				cube.y = Main.CUBE_SIZE * i+1000;
			}

			//Rendering Start
			startRendering();
		}

		protected override function onRenderTick(e:Event=null) : void
		{
			rootNode.rotationY+=(stage.stageWidth/2-stage.mouseX)/70;
			physics.step();
			super.onRenderTick(e);
		}
	}
}

以下ソースです。
PV3Dを使用する場合はPapervision3DPhysicsクラスでまず物理のワールドを作ります。

physics=new Papervision3DPhysics(rootNode,9.8);

第1引数はDisplayObjectContainer3Dなのでsceneでもいいんですが、別途事前にDisplayObject3Dを作っておいてそれを割り当てておきます。
第2引数は重力です。

続いて地面を作ります。使うクラスはRigidBodyというクラス。
Papervision3DPhysicsにはcreateGround・createCube・createSphereというメソッドが用意されておりそれらを利用し3Dのオブジェクトを作っていきます。（PV3Dでオブジェクトを作っておいてそれを利用することもできるのですが、それはまた今度）

floor=physics.createGround(new WireframeMaterial(0), 2000, 0);

第2引数はサイズなんですがそれはあくまで第1引数で指定したマテリアルが表示されるサイズであって地面は延々と続いています、はず。

次にオブジェクトを作ってみます。

var cube:RigidBody=physics.createCube(matlist, Main.CUBE_SIZE, Main.CUBE_SIZE, Main.CUBE_SIZE);

最後にenterFrame内でPapervision3DPhysicsのstepメソッドを実行します。
これ忘れると動かない。

physics.step();

今さらですがBox2Dやってみました。というか仕事で物理演算使わなきゃいけなかったので触らざるを得なかったというか。
Box2Dのバージョンは2.0.2です。

PV3Dとか他のライブラリとちょっと勝手が違うので最初とまどいましたが。
サンプルのはボックスとサークルを20個ずつNewしてボックスの質量をサークルの質量の100倍にしてます。
ボタンを押したら上下左右ランダムに力を加えてあげてます。

PV3Dとか組み合わせたらおもしろそう。

以下汚いですけどソースです。
（一度全ソース載せましたが長くて表示が遅くなってしまったのでボタン部分とボックス部分、他をちょっと削除します。。）

	import Box2D.Collision.*;
	import Box2D.Collision.Shapes.*;
	import Box2D.Common.Math.*;
	import Box2D.Common.*;
	import Box2D.Dynamics.*;
	import Box2D.Common.Math.b2Vec2;

	public class Main extends Sprite
	{
		private var m_physScale:uint = 100;
		private var world:b2World;
		private var m_sprite:Sprite;
		private var m_iterations:int = 10;
		private var m_timeStep:Number = 1 / 30;

		public function Main():void
		{
			init();
		}

		private function init():void
		{
			var worldAABB:b2AABB = new b2AABB();
			worldAABB.lowerBound.Set( -100, -100);
			worldAABB.upperBound.Set(100, 100);

			var gravity:b2Vec2 = new b2Vec2(0, 9.8);

			world = new b2World(worldAABB, gravity, true);

			var wxArr:Array = [0, stage.stageWidth, stage.stageWidth / 2, stage.stageWidth / 2];
			var wyArr:Array = [stage.stageHeight / 2, stage.stageHeight / 2, 0, stage.stageHeight];
			var wwArr:Array = [10, 10, stage.stageWidth, stage.stageWidth];
			var whArr:Array = [stage.stageHeight, stage.stageHeight, 10, 10];

			//Wall
			for (var j:uint = 0; j < 4; j++)
			{
				var floorBodyDef:b2BodyDef = new b2BodyDef();
				floorBodyDef.position.Set(wxArr[j] / m_physScale, wyArr[j] / m_physScale);

				var floorShapeDef:b2PolygonDef = new b2PolygonDef();
				floorShapeDef.SetAsBox(wwArr[j] / 2 / m_physScale, whArr[j]/2 / m_physScale);

				var floorBody:b2Body = world.CreateBody(floorBodyDef);
				floorBody.CreateShape(floorShapeDef);
			}

			//Circle
			for (var i:uint = 0; i < 20; i++)
			{
				var circleBodyDef:b2BodyDef = new b2BodyDef();
				circleBodyDef.position.Set(stage.stageWidth / 2 / m_physScale, 200 / m_physScale);

				var circleShapeDef:b2CircleDef = new b2CircleDef();
				circleShapeDef.radius = Math.random()*0.3+0.05;
				circleShapeDef.density = 1;
				circleShapeDef.friction = 0.5;
				circleShapeDef.restitution = 0.5;

				var circleBody:b2Body = world.CreateBody(circleBodyDef);
				circleBody.CreateShape(circleShapeDef);
				circleBody.SetMassFromShapes();
			}

			//Debug
			m_sprite = new Sprite();
			var debugDraw:b2DebugDraw = new b2DebugDraw();
			debugDraw.m_fillAlpha = 0.3;
			debugDraw.m_drawScale = m_physScale;
			debugDraw.m_lineThickness = 1;
			debugDraw.m_sprite = m_sprite;
			debugDraw.m_drawFlags = b2DebugDraw.e_shapeBit | b2DebugDraw.e_jointBit;
			world.SetDebugDraw(debugDraw);
			addChild(m_sprite);

			addEventListener(Event.ENTER_FRAME, update);
		}

		private function update(e:Event):void
		{
			world.Step(m_timeStep, m_iterations);
		}
	}